The Formula Column is one of the more popular ways to manipulate data on monday.com. From simple mathematical calculations to more complicated formulas, by utilizing our library of available functions, the Formula Column can help you simplify complex problems.

Below you'll find some of the most common ways to use the Formula Column ⬇️

Why your automation or email isn't working with a formula column

If you're trying to trigger an automation when a formula column changes, use a formula value in an automated email or notification, or have a chart or dashboard widget display formula results, and it isn't working as expected, this is the reason why.

A formula column calculates its result dynamically and is read-only. Because of this, it cannot act as a trigger for an automation (for example, "when formula goes above 80%, change status"), and its output is not always recognized by automated emails, notifications, charts, dashboard widgets, or cross-board actions such as mirroring or board-to-board copying.

The standard workaround: copy the formula result to a regular column

The most reliable fix across all of these scenarios (automations, emails, notifications, charts, dashboards, mirrored columns, and cross-board copying) is to copy the formula result into a regular Numbers or Text column using a workflow, then point your automation, email, or widget at that column instead.

To set this up:

1Add a regular Numbers or Text column to your board to act as the helper column.

2Create a workflow that copies the value from your formula column into the helper column whenever the relevant data on your item changes.

3Set your automation trigger, email action, chart, or dashboard widget to reference the helper column instead of the formula column.

Adding or subtracting days from a date

In this example, we want to add 15 days to each date from the column "Start Date":

ADD_DAYS({Start Date},15)

If we wanted to subtract 15 days instead, we would use the function SUBTRACT_DAYS() in place of ADD_DAYS().

SUBTRACT_DAYS({Start Date},15)

Both of the above formulas will show you an unformatted result that may look a little clunky. This is why we recommend using the following formula. The result is formatted and will look cleaner on your board:

FORMAT_DATE(ADD_DAYS({Start Date},15))

If you want to remove the year and simply see the month and day, you can further customize your formula by using the LEFT() function. In the following formula, the LEFT() function takes the output of the FORMAT_DATE() function and only outputs 6 characters from the left:

LEFT(FORMAT_DATE(ADD_DAYS({Start Date},15)),6)

If we change the 6 in the formula, we change the number of characters that the formula outputs. The results of this formula can be seen in the "LEFT" column:

Calculating days between a date and today

One really useful and dynamic function is TODAY(). Using this with the DAYS() function, you can calculate the number of days until the due date (or past the due date). When using TODAY(), you don't need to include anything within the parentheses.

We've also encapsulated the output of the DAYS() function within the ROUND() function. In this case, we're indicating that we want to round the output to 0 decimal places.

ROUND(DAYS({Due Date},TODAY()),0)

Determining the number of working days between two dates

If you're using a board to track employee vacation requests, a formula can be useful for calculating the number of working days the employee will need. The WORKDAYS() function will return the number of working days between two dates. Working days are defined, according to your account settings, as Monday to Friday or Sunday to Thursday. To learn more about this account setting, check out this article.

WORKDAYS({To},{From})

Calculate the length of a timeline (number of days or working days)

If you have a Timeline column and want to show its duration in a separate column, you have two options:

Option A — Native connection (no formula needed): Add a Numbers column to your board. Click the three-dot menu on the Numbers column → Settings → Connect to a Timeline column. monday.com will automatically calculate the duration in days.

Option B — Formula column using WORKDAYS: If you need to exclude weekends, add a Formula column and use:

WORKDAYS({Timeline#End},{Timeline#Start})

This returns the number of working days between the start and end of the timeline. The #End and #Start suffixes reference the end and start dates within a Timeline column.

Calculating billable total using the time tracking column

When using the Time Tracking Column with the Formula Column, you can choose whether you want to pull in seconds, minutes, or hours. For the following formula, we're using the "Billable" column's hours. We're also using the ROUND() function again to clean up our decimals. The number 2 in this formula signifies two decimal places.

ROUND(MULTIPLY({Billable#Hours},{Hourly Rate}),2)

Totalling hours worked excluding breaks

In this example, I'd like to calculate how long my contractors have worked. This should not include their unpaid break time. Using four Hour Columns, I can create a formula to calculate this.

IF(HOURS_DIFF({Break End}, {Break Start}) > "0", HOURS_DIFF(HOURS_DIFF({End}, {Start}), HOURS_DIFF({Break End}, {Break Start})), HOURS_DIFF({End}, {Start}))

This formula says that if the break is greater than 0, calculate the total hours worked minus the break. If the break is not greater than 0, calculate the total hours worked.

Here's how the formula works:

Calculating the change between two values

In this board, we're looking at the total sales per month for four employees. To calculate the change between the results of January and February as a percentage, you would use the following formula:

MULTIPLY(DIVIDE(MINUS({February Sales},{January Sales}),{January Sales}),100)

This formula can also be written as:

((({February Sales}-{January Sales})/{January Sales})*100)

Outputting a value based on two conditions

Now we want to calculate each employee's bonus. An employee will receive a bonus only if the "Total Sales" are higher than $350,000 and if the number of deals in the "Deals" column is higher than 12:

IF(AND({Total Sales}>350000,{Deals}>12),250,0)

The AND() function checks whether the two conditions are true. Based on the result, the IF() statement tells the formula column which value to return.

Using status labels to assign commission rates

In this example, let's say I manage a sales team with varying commission rates per salesperson. You can use the labels from the status column to indicate a specific rate within your formula:

IF({Rate}="Rate 1",25,IF({Rate}="Rate 2",20,IF({Rate}="Rate 3",15,IF({Rate}="Rate 4",10,IF({Rate}="Rate 5",5)))))

The "Commission %" column displays the relevant rate based on the selected status label.

You can take this formula a step further by calculating the commission based on the rate and the "Total Sales" column, using the MULTIPLY() function. Just keep in mind that if you use a decimal in a formula, you must write 0.25 rather than .25 to avoid an illegal formula error.

IF({Rate}="Rate 1",MULTIPLY(0.25,{Total Sales}),IF({Rate}="Rate 2",MULTIPLY(0.20,{Total Sales}),IF({Rate}="Rate 3",MULTIPLY(0.15,{Total Sales}),IF({Rate}="Rate 4",MULTIPLY(0.10,{Total Sales}),IF({Rate}="Rate 5",MULTIPLY(0.05,{Total Sales}))))))

Comparing a dynamic value to a static value

If you're using a board to track your budget, this formula may come in handy. In this example, the travel budget for each employee is $6,500. We want to determine if the total amount spent on each employee is within the budget or exceeds it. To do this, we will compare the SUM() of the values in four columns to the budget with an IF() statement.

IF(SUM({Flight},{Hotel},{Insurance},{Expenses})>6500, "Over Budget","Good")

Tracking inventory

You can easily manage your inventory with monday.com. This example explains how to calculate your current available stock and how much inventory was sold (as a percentage).

For the "In Stock" column:

MINUS(MINUS({Starting Inventory},{Reserved}),{Sold})

For the "% Sold" column:

ROUND(MULTIPLY(DIVIDE({Sold},{Starting Inventory}),100),2)

Formatting a formula

By using the TEXT() function, you can format your results exactly the way you want. Let's take a simple example from the first line of the following board. We want to multiply 100 by 25, and we want the output to display as $2,500.00.

TEXT(MULTIPLY({Starting Inventory},{Cost}),"$#,##.00")

In the last part of the formula, each # represents a number. We added .00 to the end because we want the output to end with two zeros, but you can replace this with .## if you want your output to end with calculated numbers. The $ places the symbol in front of the number.

Keep in mind that if you format a number using the TEXT() function, the formula column will read the number as text rather than a number. This means that your column summary will show "N/A" (as above) instead of the sum/average/etc of the numbers shown in your formula column.

Show the day of the week or time for an item

To display the day of the week from a Date column, add a Formula column and use:

TEXT({Date},"dddd")

This returns the full day name (for example, “Monday”). For a short name (for example, “Mon”), use:

TEXT({Date},"ddd")

To extract the hour from a Creation Log or Last Updated column, use:

HOUR({Creation Log})

Trigger an action only during business hours

Native automations cannot check the time of day an item was created. To trigger actions only during specific hours or days, use this multi-step approach:

1. Add a Creation Log column to your board (it auto-captures when each item was created).

2. Add a Formula column to evaluate the condition. For business hours Monday–Friday, 9am–6pm:

IF(AND(HOUR({Creation Log})>=9, HOUR({Creation Log})<18, WEEKDAY({Creation Log})>=2, WEEKDAY({Creation Log})<=6), "Yes", "No")

This returns “Yes” if the item was created during business hours, “No” otherwise.

3. Go to Automate → Workflows. Build a workflow: When item is created → Change column value (set a Status column based on the formula result) → Only continue if Status is “Yes” → your action.

Note: WEEKDAY returns 1 for Sunday and 7 for Saturday, so weekdays are 2–6.

Summarize numbers in a Mirror Column

The Formula Column can be used to summarize a Mirror Column, as long as the column being mirrored is a Numbers Column. To create this summary, add the Formula column to your board and use the following function:

SUM({Mirror})

For example, we will use a Mirror Column on a high-level board to display the project budget. The column "Budget" is a Numbers Column from a related low-level board.

The Formula Column will then pull the numbers from within the Mirror Column and generate a summary at the bottom of the column.

Limitations

Below are common limitations that come up when building formulas on a board:

• The Formula column calculates horizontally (per item) and cannot sum an entire column. The Formula column can reference values in other columns on the same item (row), but it does not work like Excel where you can sum a full column of values across multiple items. If you need a total across items, use the Numbers column summary at the bottom of the column, or use a board view or dashboard to aggregate your data.
• Formula results cannot be written into other columns (for example, a Date column). A formula can display a calculated result in the Formula column, but it cannot populate another column inside the platform on its own. If you need to copy a formula result into another column, use a workflow as a workaround.
• Formula columns cannot trigger automations or populate automated emails, charts, or dashboard widgets directly. Because formula output is read-only, it is not recognized as a standard column value by automations, email actions, notifications, or most widgets. To work around this, copy the formula result into a regular column using a workflow, then point your automation or widget at that column. See the Why your automation or email isn't working with a formula column section above for the full setup.
• Formula columns from mirrored or cloned boards may not behave as expected. If you are copying a board, using a mirror column that references a formula column, or using an app to move data between boards, the formula output may not transfer correctly. The same workaround applies: copy the formula result into a regular column first, then reference that column in your automation or cross-board setup.
• "Unsupported column with calculation" error in the formula editor. This error appears when a formula references a Numbers column that behaves as a calculated field rather than a standard input column. If you see this error, check whether the column you are referencing is itself a formula or calculated column type, and replace it with a standard Numbers column input where possible.

FAQs

Can I use a formula column to trigger an automation on monday.com?

Not directly. Formula columns are read-only and cannot act as automation triggers. The workaround is to copy the formula result into a regular Numbers column using a workflow, then set your automation to trigger from that column instead.

Why is my formula value not showing in an automated email or notification?

Formula output is not always recognized by email actions and notifications inside monday.com. Copy the formula result into a regular column using a workflow, then reference that column in your email or notification action.

Why does my chart or dashboard widget show zero for a formula column?

Some chart and dashboard widgets do not read formula column output the same way they read standard number inputs. Copy the formula result into a regular Numbers column using a workflow, then point the widget at that column to display the correct values.

What does the "Unsupported column with calculation" error mean in the formula editor?

This error appears when a formula references a column that is itself calculated rather than a standard input. Check whether the referenced column is a formula or calculated column type, and replace it with a standard Numbers column where possible.

Can I copy a formula column result to another board on monday.com?

Formula output does not always transfer correctly when cloning a board, using a mirror column, or moving data between boards with an app. Copy the formula result into a regular column first using a workflow, then use that column as the source for any cross-board action.