A coluna de fórmula é uma das maneiras mais populares de manipular dados na monday.com. De simples cálculos matemáticos a fórmulas mais complicadas e com o uso da nossa biblioteca de funções disponíveis, a coluna de fórmula pode ajudar você a simplificar problemas complexos.

Antes de mergulharmos neste artigo, você encontrará no quadro abaixo alguns dos nossos casos de uso mais comuns para a coluna de fórmula:

 

Fique à vontade para copiar e colar a fórmula fornecida na coluna de fórmula diretamente no seu quadro para poder utilizá-la!

 

Agora, vamos explorar ainda mais os casos de uso que reunimos. Abaixo, você encontrará algumas das formas mais comuns de usar a coluna de fórmula ⬇️

 

Adicionar ou remover dias de uma data

Neste exemplo, queremos adicionar 15 dias em cada data da coluna "data inicial": 

ADD_DAYS({Start Date},15) 

Se quisermos diminuir 15 dias, podemos usar a função SUBTRACT_DAYS() no lugar de ADD_DAYS().

SUBTRACT_DAYS({Start Date},15) 

Ambas as fórmulas acima mostrarão um resultado não formatado que pode parecer meio esquisito. É por isso que recomendamos usar a fórmula a seguir. O resultado estará formatado e terá uma aparência mais clara no seu quadro: 

FORMAT_DATE(ADD_DAYS({Start Date},15))

Se você quiser remover o ano e ver apenas o dia e o mês, pode personalizar ainda mais a sua fórmula ao usar a função LEFT(). Na fórmula a seguir, a função LEFT() usa o resultado da função FORMAT_DATE() e exibe somente 6 caracteres a partir da esquerda:

LEFT(FORMAT_DATE(ADD_DAYS({Start Date},15)),6)

Se alterarmos o 6 na fórmula, mudamos o número de caracteres exibidos no resultado dela. Os resultados dessa fórmula podem ser vistos na coluna "LEFT":

 

Calcular dias entre a data e hoje

Uma função muito útil e dinâmica é a TODAY(). Ao usá-la com a função DAYS(), você pode calcular o número de dias até a data limite (ou após a data limite). Ao usar TODAY(), você não precisa incluir nada entre parênteses.

Também encapsulamos o resultado da função DAYS() na função ROUND(). Neste caso, estamos indicando que queremos arredondar o resultado com 0 casas decimais.  

ROUND(DAYS({Due Date},TODAY()),0)

 

Determinar o número de dias úteis entre duas datas

Se você estiver usando um quadro para acompanhar as solicitações de férias dos funcionários, pode ser útil usar uma fórmula ao calcular o número de dias úteis que o funcionário vai precisar. A função a seguir, WORKDAYS(), retornará o número de dias úteis entre duas datas. Os dias úteis são definidos, de acordo com as configurações da sua conta, como de segunda a sexta-feira ou de domingo a quinta-feira. Para saber mais sobre essas configurações de conta, confira este artigo.

WORKDAYS({To},{From})

 

Calcular o total faturável usando a coluna de controle de tempo 

Ao usar a coluna de controle de tempo com a coluna de fórmula, é possível escolher se deseja os dados em segundos, minutos ou horas. Para a fórmula a seguir, estamos usando as horas da coluna "faturável". Também estamos usando a função ROUND() novamente para remover os decimais. O número 2 nessa fórmula indica duas casas decimais.

ROUND(MULTIPLY({Billable#Hours},{Hourly Rate}),2)

 

Total de horas trabalhadas excluindo os intervalos

Neste exemplo, gostaria de calcular quanto tempo meus contratados trabalharam. E isso não deve incluir o período de intervalo não remunerado. Usando quatro colunas de hora, posso criar uma fórmula para calcular isso. 

IF(HOURS_DIFF({Break End}, {Break Start}) > "0", HOURS_DIFF(HOURS_DIFF({End}, {Start}), HOURS_DIFF({Break End}, {Break Start})), HOURS_DIFF({End}, {Start}))

Essa fórmula diz que, se o intervalo for maior que 0, será calculado o total de horas trabalhadas sem os intervalos. Se o intervalo não for maior que 0, calcula-se o número total de horas trabalhadas.

Aqui está como a fórmula funciona:

 

Calcular a alteração entre dois valores

Neste quadro, vemos as vendas totais por mês para quatro funcionários. Para calcular a alteração entre os resultados de janeiro e fevereiro em porcentagem, você deve usar a seguinte fórmula:

MULTIPLY(DIVIDE(MINUS({February Sales},{January Sales}),{January Sales}),100)

Essa fórmula também pode ser escrita como:

((({February Sales}-{January Sales})/{January Sales})*100)

 

Resultado de um valor com base em duas condições

Agora, queremos calcular o bônus de cada funcionário. Um funcionário receberá o bônus somente se as "vendas totais" forem superiores a 350.000 e se o número de negócios na coluna "negócios" for maior que 12:

IF(AND({Total Sales}>350000,{Deals}>12),250,0)

A função AND() verifica se as duas condições são verdadeiras. Com base no resultado, a instrução IF() informa à coluna de fórmula qual valor devolver.

 

Usar etiquetas de status para atribuir taxas de comissão

Neste exemplo, digamos que eu gerencie uma equipe de vendas com taxas de comissão variáveis entre os vendedores.  Você pode usar etiquetas na coluna de status para indicar uma taxa específica na sua fórmula: 

IF({Rate}="Rate 1",25,IF({Rate}="Rate 2",20,IF({Rate}="Rate 3",15,IF({Rate}="Rate 4",10,IF({Rate}="Rate 5",5)))))

A coluna "% de comissão" exibe a taxa relevante, de acordo com a etiqueta de status selecionada.

Você pode ir adiante com essa fórmula e calcular a comissão com base na taxa e na coluna "total de vendas" ao incorporar a função MULTIPLY(). Tenha em mente que, se usar um decimal em uma fórmula, deverá escrever 0.25 em vez de .25 para evitar erro.

IF({Rate}="Rate 1",MULTIPLY(0.25,{Total Sales}),IF({Rate}="Rate 2",MULTIPLY(0.20,{Total Sales}),IF({Rate}="Rate 3",MULTIPLY(0.15,{Total Sales}),IF({Rate}="Rate 4",MULTIPLY(0.10,{Total Sales}),IF({Rate}="Rate 5",MULTIPLY(0.05,{Total Sales}))))))

 

Comparar um valor dinâmico com um valor estático

Se você estiver usando um quadro para acompanhar seu orçamento, essa fórmula pode ser bastante útil. Neste exemplo, o orçamento de viagem de cada funcionário é de 6.500. Queremos descobrir se o valor total gasto com cada funcionário está dentro do orçamento ou acima dele. Para isso, vamos comparar a soma — SUM() — dos valores em quatro colunas com o orçamento usando a instrução IF().

IF(SUM({Flight},{Hotel},{Insurance},{Expenses})>6500, "Over Budget","Good")  

 

Rastrear inventário

É fácil gerenciar seu inventário com a monday.com. Este exemplo explica como calcular o estoque atual disponível e quanto foi vendido (em porcentagem).

Para a coluna "em estoque":

MINUS(MINUS({Starting Inventory},{Reserved}),{Sold})

Para a coluna "% vendido":

ROUND(MULTIPLY(DIVIDE({Sold},{Starting Inventory}),100),2)

 

Formatação da fórmula

Ao usar a função TEXT(), você pode formatar seus resultados do jeito que quiser. Vamos ver um exemplo simples na primeira linha do quadro a seguir. Queremos multiplicar 100 por 25 e que o resultado seja exibido assim: $2,500.00.

TEXT(MULTIPLY({Starting Inventory},{Cost}),"$#,##.00")

Na última parte da fórmula, cada # representa um número. Adicionamos .00 ao final porque queremos que o resultado termine com dois zeros, mas você pode substituir por ,## se quiser que o resultado termine com os números calculados. O $ indica o símbolo na frente do número.

Tenha em mente que, se você formatar um número usando a função TEXT(), a coluna de fórmula lerá o número como texto e não como número. Isso significa que o resumo da coluna exibirá "N/A" (como acima) em vez de soma/média/etc. dos números exibidos na sua coluna de fórmula.

 

 

 

 

Se você tiver alguma dúvida, entre em contato com nossa equipe por aqui. Estamos disponíveis 24 horas e prontos para ajudar!