Pouvons-nous vous aider?

Cas d'utilisation des formules

La colonne Formule est l'un des moyens les plus pratiques de manipuler des données sur monday.com. Que vous souhaitiez effectuer des calculs mathématiques simples ou employer des formules plus élaborées, la colonne Formule utilisée conjointement à la bibliothèque des fonctions disponibles vous permettra de simplifier des problèmes complexes.

Avant que nous n'entrions dans le vif du sujet, vous trouverez dans le tableau ci-dessous une liste de nos cas d'utilisation de la colonne Formule les plus courants :

 

N'hésitez pas à copier-coller la formule proposée directement dans la colonne Formule dans votre tableau en fonction de vos besoins.

Conseil : pour accéder au tableau des cas d'utilisation des formules, vous pouvez également cliquer ici🙏

 

Examinons à présent en détail certains des cas d'utilisation que nous avons rassemblés. Vous trouverez ci-dessous quelques-unes des utilisations les plus courantes de la colonne de formule. ⬇️

Ajouter/soustraire des jours à une date

Dans cet exemple, nous voulons ajouter 15 jours à chaque date de la colonne « date de début » (« Start Date ») : 

ADD_DAYS({Start Date},15) 

Si nous souhaitions au contraire retirer 15 jours, nous utiliserions la fonction SUBTRACT_DAYS() à la place de ADD_DAYS().

SUBTRACT_DAYS({Start Date},15) 

Ces deux formules vous donneront un résultat non formaté assez peu lisible. C'est pourquoi nous recommandons d'utiliser la formule ci-dessous. Elle donne un résultat formaté, qui sera plus clair dans votre tableau : 

FORMAT_DATE(ADD_DAYS({Start Date},15))

Frame_31.png

Si vous souhaitez supprimer l'année pour n'afficher que le mois et le jour, vous pouvez encore personnaliser la formule en utilisant la fonction LEFT(). Dans la formule suivante, la fonction LEFT() prend le résultat de la fonction FORMAT_DATE() et n'en affiche que les six premiers caractères en partant de la gauche :

LEFT(FORMAT_DATE(ADD_DAYS({Start Date},15)),6)

Si nous remplaçons le « 6 » de la formule par un autre chiffre, nous changeons le nombre de caractères que la formule affiche.

Les résultats de cette formule sont visibles dans la colonne « LEFT » :

Frame_31__1_.png

 

Calculer le nombre de jours entre une date et aujourd'hui

La fonction dynamique TODAY() est très utile, elle aussi. Utilisez-la avec la fonction DAYS() pour calculer le nombre de jours jusqu'à la date d'échéance (ou après la date d'échéance). Lorsque vous utilisez TODAY(), vous n'avez pas besoin d'inclure quoi que ce soit entre les parenthèses.

Nous avons par ailleurs encapsulé le résultat de la fonction DAYS() dans la fonction ROUND(). Ici, nous indiquons que nous voulons arrondir le résultat à zéro décimale.  

ROUND(DAYS({Due Date},TODAY()),0)

Frame_38.png

 

Déterminer le nombre de jours ouvrables entre deux dates

Si vous utilisez un tableau pour suivre les demandes de congés de vos employés, une formule vous aidera à calculer le nombre de jours travaillés nécessaire à vos employés. La fonction suivante, WORKDAYS(), affiche le nombre de jours ouvrables entre deux dates. Selon les paramètres de votre compte, les jours ouvrables courent du lundi au vendredi ou du dimanche au jeudi. Pour en savoir plus sur ce paramètre du compte, consultez cet article.

WORKDAYS({To},{From})

Frame_39.png

 

Calculer le total facturable à l'aide de la colonne Chronomètre 

Lorsque vous utilisez la colonne Chronomètre avec la colonne Formule, vous pouvez choisir d'extraire des secondes, des minutes ou des heures. Dans la formule suivante, nous utilisons les heures de la colonne « Facturable » (« Billable »). Nous l'associons à la fonction ROUND() pour limiter le nombre de décimales. Le chiffre « 2 » de la formule signifie deux décimales.

ROUND(MULTIPLY({Billable#Hours},{Hourly Rate}),2)

Frame_32__2_.png

 

Faire le total des heures travaillées hors pauses

Dans cet exemple, je souhaite calculer le temps travaillé par mes prestataires, moins leur temps de pause non payé. En utilisant quatre colonnes Heure, je peux créer une formule pour le calculer. 

IF(HOURS_DIFF({Break End}, {Break Start}) > "0", HOURS_DIFF(HOURS_DIFF({End}, {Start}), HOURS_DIFF({Break End}, {Break Start})), HOURS_DIFF({End}, {Start}))

Cette formule indique de calculer le total des heures travaillées moins la pause, si la pause (« break ») est supérieure à zéro. Si la pause n'est pas supérieure à zéro, la formule calcule le total des heures travaillées.

Voici comment la formule fonctionne :

Frame_33.png

 

Calculer la variation entre deux valeurs

Dans ce tableau, nous examinons le chiffre d'affaires mensuel de quatre employés. Pour calculer le taux de variation entre les résultats de janvier et ceux de février, nous utilisons la formule suivante :

MULTIPLY(DIVIDE(MINUS({February Sales},{January Sales}),{January Sales}),100)

Cette formule peut également s'écrire de cette façon :

((({February Sales}-{January Sales})/{January Sales})*100)

Frame_35__1_.png

 

Calculer une valeur dépendante de deux conditions

Nous souhaitons à présent calculer la prime de chaque employé. Un employé obtiendra une prime uniquement si le chiffre d'affaires (« Total Sales ») est supérieur à 350 000 $ et si le nombre de transactions dans la colonne Ventes (« Deals ») est supérieur à douze :

IF(AND({Total Sales}>350000,{Deals}>12),250,0)

La fonction AND() vérifie si les deux conditions sont vraies. En fonction du résultat, l'instruction IF() indique à la colonne Formule la valeur à renvoyer.

Frame_36__3_.png

 

Utiliser des étiquettes d'état pour attribuer des taux de commission

Dans cet autre exemple, admettons que je gère une équipe commerciale avec des taux de commission différents selon les commerciaux.  Je peux utiliser les étiquettes de la colonne Statut pour indiquer un taux (« rate ») spécifique dans la formule : 

IF({Rate}="Rate 1",25,IF({Rate}="Rate 2",20,IF({Rate}="Rate 3",15,IF({Rate}="Rate 4",10,IF({Rate}="Rate 5",5)))))

La colonne « Commission % » indique le taux adéquat selon l'étiquette de statut sélectionnée.

Frame_40.png

Vous pouvez aller encore plus loin et calculer la commission en fonction du taux de commission et de la colonne « Chiffre d'affaires » en intégrant la fonction MULTIPLY() à la formule. Gardez simplement à l'esprit que si vous utilisez une décimale dans une formule, vous devez écrire 0.25 plutôt que .25 pour éviter une erreur de formule non valide.

IF({Rate}="Rate 1",MULTIPLY(0.25,{Total Sales}),IF({Rate}="Rate 2",MULTIPLY(0.20,{Total Sales}),IF({Rate}="Rate 3",MULTIPLY(0.15,{Total Sales}),IF({Rate}="Rate 4",MULTIPLY(0.10,{Total Sales}),IF({Rate}="Rate 5",MULTIPLY(0.05,{Total Sales}))))))

Frame_41__1_.png

 

Comparer une valeur dynamique à une valeur statique

Si vous utilisez un tableau pour suivre votre budget, cette formule peut vous être utile. Dans cet exemple, le budget pour les déplacements de chaque employé est de 6 500 $. Nous souhaitons savoir si le montant total dépensé pour chaque employé se situe dans le budget ou au-dessus. Pour ce faire, nous allons comparer la somme (SUM()) des valeurs des quatre colonnes au budget à l'aide d'une instruction IF().

IF(SUM({Flight},{Hotel},{Insurance},{Expenses})>6500, "Over Budget","Good")  

Frame_37__1_.png

 

Suivre l'inventaire

Vous pouvez facilement gérer votre inventaire avec monday.com. Cet exemple vous explique comment calculer votre stock disponible actuel et quel part (en pourcentage) de l'inventaire a été vendue.

Pour la colonne « En stock » (« In Stock ») :

MINUS(MINUS({Starting Inventory},{Reserved}),{Sold})

Frame_42.png

Pour la colonne « % vendu » (« % Sold ») :

ROUND(MULTIPLY(DIVIDE({Sold},{Starting Inventory}),100),2)

Frame_43__1_.png

 

Formater une formule

Utilisez la fonction TEXT() pour formater vos résultats exactement comme vous le souhaitez. Prenons un exemple simple : la première ligne du tableau ci-dessous. Nous voulons multiplier 100 par 25, et que le résultat s'affiche au format suivant : $2,500.00.

TEXT(MULTIPLY({Starting Inventory},{Cost}),"$#,##.00")

Frame_44__1_.png

Dans la dernière partie de la formule, chaque # représente un nombre. Nous avons ajouté .00 à la fin de la formule parce que nous voulons que le résultat se termine par .00, mais vous pouvez remplacer ces deux zéros par .##, si vous voulez que votre résultat se termine par des chiffres calculés. Le symbole $ doit être placé avant le résultat.

N'oubliez pas que si vous formatez un nombre à l'aide de la fonction TEXT(), la colonne Formule lira ce nombre comme du texte plutôt que comme un nombre. Par conséquent, le résumé de la colonne Formule indiquera « N/A » (comme ci-dessus) au lieu de la somme/moyenne/etc. des nombres de la colonne.

 

Nous sommes à votre disposition si vous avez d'autres questions. Consultez la FAQ sur les formules du forum de la Communauté ou contactez notre équipe via le formulaire de contact. Nous sommes disponibles 24 h/24, 7 j/7, et nous nous ferons un plaisir de vous aider. 🙂