La columna fórmula es una de las formas más populares de manipular datos en monday.com. Desde cálculos matemáticos simples a fórmulas más complicadas, la columna fórmula puede ayudarte a simplificar problemas complejos utilizando nuestra biblioteca de funciones disponibles.

Antes de profundizar en este artículo, en el tablero que aparece a continuación encontrarás algunos de nuestros casos de uso más comunes para la columna fórmula:

 

Puedes copiar y pegar la fórmula proporcionada en la columna fórmula directamente en tu propio tablero para usarla.

 

Ahora, exploremos en más detalle alguno de los casos de uso que recolectamos. A continuación, encontrarás las formas más comunes de usar la columna Fórmula ⬇️

 

¿Cómo agregar o eliminar días de una fecha?

En este ejemplo, queremos agregar 15 días a cada fecha de la columna "Start Date" (Fecha de inicio): 

ADD_DAYS({Start Date},15) 

Si, en cambio, quisiéramos quitar 15 días, deberíamos usar la función SUBTRACT_DAYS() en lugar de ADD_DAYS().

SUBTRACT_DAYS({Start Date},15) 

Las dos fórmulas que aparecen arriba te mostrarán un resultado sin formato que posiblemente se vea un poco desprolijo. Por este motivo, recomendamos usar la siguiente fórmula. El resultado tiene formato y se verá más claro en tu tablero: 

FORMAT_DATE(ADD_DAYS({Start Date},15))

Si quieres eliminar el año y simplemente ver el mes y el día, puedes personalizar tu fórmula usando la función LEFT(). En la siguiente fórmula, la función LEFT() toma el resultado de la función FORMAT_DATE() y solo genera 6 caracteres de la izquierda:

LEFT(FORMAT_DATE(ADD_DAYS({Start Date},15)),6)

Si cambiamos el 6 en la fórmula, cambiamos el número de caracteres que genera la fórmula. Los resultados de esta fórmula se pueden ver en la columna de la "IZQUIERDA":

 

¿Cómo calcular los días entre una fecha y hoy?

Una función muy útil y dinámica es TODAY(). Si la usas con la función DAYS(), puedes calcular cuántos días faltan para la fecha límite (o pasaron desde la fecha límite). Cuando usas TODAY(), no es necesario que incluyas nada dentro de los paréntesis.

Además, encapsulamos el resultado de la función DAYS() dentro de la función ROUND(). En este caso, estamos indicando que queremos redondear el resultado con 0 lugares decimales.  

ROUND(DAYS({Due Date},TODAY()),0)

 

¿Cómo determinar la cantidad de días laborales entre dos fechas?

Si estás usando un tablero para hacer un seguimiento de las solicitudes de vacaciones de los empleados, sería útil que aplicaras una fórmula para calcular la cantidad de días laborales que necesitará el empleado. La siguiente función, WORKDAYS(), devolverá la cantidad de días laborales entre dos fechas. Los días laborales se definen, según la configuración de tu cuenta, como lunes a viernes o domingo a jueves. Para obtener más información sobre la configuración de la cuenta, consulta este artículo.

WORKDAYS({To},{From})

 

¿Cómo calcular el total para facturar usando la columna seguimiento de tiempo? 

Si usas la columna seguimiento de tiempo con la columna fórmula, puedes elegir si quieres que aparezcan los segundos, minutos u horas. En la siguiente fórmula, usamos las horas de la columna "Billable" (Para facturar). También usamos la función ROUND() nuevamente para quitar decimales. El número 2 en esta fórmula significa dos lugares decimales.

ROUND(MULTIPLY({Billable#Hours},{Hourly Rate}),2)

 

¿Cómo calcular el total de las horas trabajadas sin incluir los descansos?

En este ejemplo, quisiera calcular cuánto tiempo trabajaron mis contratistas. No quiero incluir el tiempo de descanso no pago. Con cuatro columnas hora, puedo crear una fórmula para calcularlo. 

IF(HOURS_DIFF({Break End}, {Break Start}) > "0", HOURS_DIFF(HOURS_DIFF({End}, {Start}), HOURS_DIFF({Break End}, {Break Start})), HOURS_DIFF({End}, {Start}))

Esta fórmula dice que si el descanso es mayor a 0, se debe calcular el total de horas trabajadas menos el descanso. Si el descanso no es mayor a 0, se deben calcular las horas totales trabajadas.

Así es como funciona la fórmula:

 

¿Cómo calcular el cambio entre dos valores?

En este tablero, analizamos el total de ventas por mes de cuatro empleados. Para calcular el cambio entre los resultados de enero y febrero como porcentaje, se puede usar la siguiente fórmula:

MULTIPLY(DIVIDE(MINUS({February Sales},{January Sales}),{January Sales}),100)

Esta fórmula también se puede escribir de la siguiente manera:

((({February Sales}-{January Sales})/{January Sales})*100)

 

¿Cómo obtener como resultado un valor basado en dos condiciones?

Ahora queremos calcular la bonificación de cada empleado. Un empleado recibirá una bonificación solo si "Total Sales" (Ventas totales) es mayor que $350 000 y si la cantidad de operaciones en la columna "Deals" (Acuerdos) es mayor que 12:

IF(AND({Total Sales}>350000,{Deals}>12),250,0)

La función AND() comprueba si las dos condiciones son verdaderas. Según el resultado, el enunciado IF() le indica a la columna fórmula qué resultado devolver.

 

¿Cómo usar las etiquetas de estados para asignar tarifas de comisión?

En este ejemplo, supongamos que gestiono un equipo de ventas con diferentes tarifas de comisión por vendedor.  Puedes usar las etiquetas de la columna estado para indicar una tarifa específica dentro de tu fórmula: 

IF({Rate}="Rate 1",25,IF({Rate}="Rate 2",20,IF({Rate}="Rate 3",15,IF({Rate}="Rate 4",10,IF({Rate}="Rate 5",5)))))

La columna "Commission %" (% de comisión) muestra la tarifa relevante según la etiqueta de estado seleccionada.

Si incorporas la función MULTIPLY(), puedes llevar esta fórmula un paso más allá y calcular la comisión según la tarifa y la columna "Total Sales" (Ventas totales). Solo ten en cuenta que si usas un decimal en una fórmula, debes escribir 0.25 en lugar de .25 para evitar un error de fórmula.

IF({Rate}="Rate 1",MULTIPLY(0.25,{Total Sales}),IF({Rate}="Rate 2",MULTIPLY(0.20,{Total Sales}),IF({Rate}="Rate 3",MULTIPLY(0.15,{Total Sales}),IF({Rate}="Rate 4",MULTIPLY(0.10,{Total Sales}),IF({Rate}="Rate 5",MULTIPLY(0.05,{Total Sales}))))))

 

¿Cómo comparar un valor dinámico con un valor estático?

Si estás usando un tablero para realizar un seguimiento de tu presupuesto, quizá esta fórmula te resulte útil. En este ejemplo, el presupuesto de viaje para cada empleado de es $6500. Queremos saber si el monto total que se gasta en cada empleado está dentro del presupuesto o lo supera. Para hacerlo, compararemos la SUM() de los valores en cuatro columnas con el presupuesto, para hacerlo usaremos un enunciado IF().

IF(SUM({Flight},{Hotel},{Insurance},{Expenses})>6500, "Over Budget","Good")  

 

¿Cómo realizar un seguimiento del inventario?

Puedes gestionar fácilmente tu inventario con monday.com. Este ejemplo explica cómo calcular tu stock disponible actual y cuánto inventario se vendió (como un porcentaje).

Para la columna "In Stock" (En stock):

MINUS(MINUS({Starting Inventory},{Reserved}),{Sold})

Para la columna "% Sold" (% vendido):

ROUND(MULTIPLY(DIVIDE({Sold},{Starting Inventory}),100),2)

 

¿Cómo dar formato a una fórmula?

Al usar la función TEXT(), puedes dar formato a tus resultados de la manera que quieras. Veamos un ejemplo fácil en la primera línea del siguiente tablero. Queremos multiplicar 100 por 25, y queremos que el resultado se vea así: $2,500.00.

TEXT(MULTIPLY({Starting Inventory},{Cost}),"$#,##.00")

En la última parte de la fórmula, cada # representa un número. Agregamos .00 al final porque queremos que el resultado finalice con dos ceros, pero puedes reemplazar esto con .## si quieres que el resultado finalice con números calculados. El $ coloca el símbolo delante del número.

Ten en cuenta que si le das formato a un número usando la función TEXT(), la columna fórmula leerá el número como texto en vez de como número. Esto significa que el resumen de tu columna mostrará "N/A" (como aparece arriba) en vez de la suma/promedio/etc. de los números que se muestran en tu columna fórmula.

 

 

 

 

Si tienes preguntas, comunícate con nuestro equipo aquí. Estamos disponibles las 24 horas, los 7 días de la semana, y será un gusto ayudarte.