Die Formelspalte ist eine der beliebtesten Möglichkeiten, Daten auf monday.com zu verarbeiten. Von einfachen mathematischen Berechnungen bis hin zu komplizierteren Formeln - mit unserer Bibliothek der verfügbaren Funktionen kann die Formelspalte dir helfen, komplexe Probleme zu vereinfachen.

Bevor wir in diesen Artikel eintauchen, findest du im unteren Board einige unserer häufigsten Anwendungsfälle für die Formelspalte:

 

Kopiere einfach die in der Spalte „Formel“ angegebene Formel und füge sie direkt in dein eigenes Board ein, um sie zu verwenden!

 

Schauen wir uns nun einige der Anwendungsfälle an, die wir zusammengetragen haben. Im Folgenden findest du einige der häufigsten Verwendungsmöglichkeiten für die Formelspalte ⬇️

 

Hinzufügen oder Subtrahieren von Tagen von einem Datum

In diesem Beispiel möchten wir zu jedem Datum in der Spalte „Startdatum” 15 Tage addieren: 

ADD_DAYS({Start Date},15) 

Wenn wir stattdessen 15 Tage subtrahieren wollten, würden wir die Funktion SUBTRACT_DAYS() anstelle von ADD_DAYS() verwenden.

SUBTRACT_DAYS({Start Date},15) 

Die beiden obigen Formeln zeigen dir ein unformatiertes Ergebnis, das etwas klobig aussehen kann. Deshalb empfehlen wir die Verwendung der folgenden Formel. Das Ergebnis ist formatiert und sieht auf deinem Board sauberer aus: 

FORMAT_DATE(ADD_DAYS({Start Date},15))

Wenn du das Jahr entfernst und nur den Monat und den Tag sehen möchtest, kannst du deine Formel weiter anpassen, indem du die Funktion LEFT() verwendest. In der folgenden Formel nimmt die Funktion LEFT() die Ausgabe der Funktion FORMAT_DATE() und gibt nur 6 Zeichen von links aus:

LEFT(FORMAT_DATE(ADD_DAYS({Start Date},15)),6)

Wenn wir die 6 in der Formel ändern, ändern wir die Anzahl der Zeichen, die die Formel ausgibt. Die Ergebnisse dieser Formel sind in der LINKEN Spalte zu sehen:

 

Berechnen von Tagen zwischen einem Datum und heute

Eine wirklich nützliche und dynamische Funktion ist TODAY(). Wenn du sie mit der Funktion DAYS() verwendest, kannst du die Anzahl der Tage bis zum Fälligkeitsdatum (oder über das Fälligkeitsdatum hinaus) berechnen. Wenn du TODAY() verwendest, musst du nichts innerhalb der Klammern angeben.

Wir haben auch die Ausgabe der DAYS()-Funktion innerhalb der ROUND()-Funktion verkapselt. In diesem Fall geben wir an, dass wir die Ausgabe auf 0 Dezimalstellen runden möchten.  

ROUND(DAYS({Due Date},TODAY()),0)

 

Festlegen der Anzahl der Arbeitstage zwischen zwei Daten

Wenn du ein Board verwendest, um die Urlaubsanträge der Mitarbeiter zu verfolgen, kann eine Formel nützlich sein, um die Anzahl der Arbeitstage zu berechnen, die der Mitarbeiter benötigen wird. Die folgende Funktion, WORKDAYS(), gibt die Anzahl der Arbeitstage zwischen zwei Daten aus. Geschäftszeiten werden gemäß deinen Kontoeinstellungen definiert, von Montag bis Freitag oder von Sonntag bis Donnerstag. Weitere Informationen zu dieser Kontoeinstellung findest du in diesem Artikel.

WORKDAYS({To},{From})

 

Berechnung der fakturierbaren Summe anhand der Zeiterfassungsspalte 

Wenn du die Spalte für die Zeiterfassung mit der Formelspalte verwendest, kannst du festlegen, ob du Sekunden, Minuten oder Stunden abrechnen möchtest. Für die folgende Formel verwenden wir die Stunden in der Spalte „Fakturierbar“. Wir verwenden auch wieder die Funktion ROUND(), um unsere Dezimalzahlen zu bereinigen. Die Zahl 2 in dieser Formel steht für zwei Nachkommastellen.

ROUND(MULTIPLY({Billable#Hours},{Hourly Rate}),2)

 

Gesamtzahl der Arbeitszeiten ohne Pausen

In diesem Beispiel möchte ich berechnen, wie lange meine Auftragnehmer gearbeitet haben. Dies sollte nicht ihre unbezahlte Pausenzeit beinhalten. Mit vier Stundenspalten kann ich eine Formel erstellen, um dies zu berechnen.

IF(HOURS_DIFF({Break End}, {Break Start}) > "0", HOURS_DIFF(HOURS_DIFF({End}, {Start}), HOURS_DIFF({Break End}, {Break Start})), HOURS_DIFF({End}, {Start}))

Diese Formel besagt, dass, wenn die Pause größer als 0 ist, die gesamten Arbeitsstunden abzüglich der Pause berechnet werden. Wenn die Pause nicht größer als 0 ist, werden die Gesamtarbeitsstunden berechnet.

So funktioniert die Formel:

 

Berechnen der Änderung zwischen zwei Werten

In diesem Board betrachten wir den Gesamtumsatz pro Monat für vier Mitarbeiter. Um die Änderung zwischen den Ergebnissen von Januar und Februar als Prozentsatz zu berechnen, würdest du die folgende Formel verwenden:

MULTIPLY(DIVIDE(MINUS({February Sales},{January Sales}),{January Sales}),100)

Diese Formel kann auch geschrieben werden als:

((({February Sales}-{January Sales})/{January Sales})*100)

 

Ausgeben eines Wertes basierend auf zwei Bedingungen

Jetzt wollen wir den Bonus für jeden Mitarbeiter berechnen. Ein Mitarbeiter erhält nur dann einen Bonus, wenn der „Gesamtumsatz“ höher ist als 350.000 USD und wenn die Anzahl der Abschlüsse in der Spalte „Abschlüsse“ höher ist als 12:

IF(AND({Total Sales}>350000,{Deals}>12),250,0)

Die Funktion AND() prüft, ob die beiden Bedingungen wahr sind. Basierend auf dem Ergebnis teilt die IF()-Anweisung der Formelspalte mit, welchen Wert sie zurückgeben soll.

 

Verwenden von Statuslabels zum Zuweisen von Provisionssätzen

Nehmen wir in diesem Beispiel an, ich verwalte ein Vertriebsteam mit unterschiedlichen Provisionsraten pro Vertriebsmitarbeiter.  Du kannst die Labels aus der Statusspalte verwenden, um eine bestimmte Rate in deiner Formel anzugeben: 

IF({Rate}="Rate 1",25,IF({Rate}="Rate 2",20,IF({Rate}="Rate 3",15,IF({Rate}="Rate 4",10,IF({Rate}="Rate 5",5)))))

Die Spalte „Kommission %“ zeigt den relevanten Satz basierend auf dem ausgewählten Statuslabel an.

Du kannst diese Formel noch einen Schritt weiterführen und die Provision auf der Grundlage des Satzes und der Spalte „Gesamtumsatz“ berechnen, indem du die Funktion MULTIPLY() einbindest. Denke nur daran, dass du, wenn du eine Dezimalzahl in einer Formel verwendest, 0,25 und nicht .25 schreiben musst, um einen Formelfehler zu vermeiden.

IF({Rate}="Rate 1",MULTIPLY(0.25,{Total Sales}),IF({Rate}="Rate 2",MULTIPLY(0.20,{Total Sales}),IF({Rate}="Rate 3",MULTIPLY(0.15,{Total Sales}),IF({Rate}="Rate 4",MULTIPLY(0.10,{Total Sales}),IF({Rate}="Rate 5",MULTIPLY(0.05,{Total Sales}))))))

 

Vergleich eines dynamischen Wertes mit einem statischen Wert

Wenn du ein Board verwendest, um dein Budget im Auge zu behalten, könnte diese Formel nützlich sein. In diesem Beispiel beträgt das Reisebudget für jeden Mitarbeiter 6.500 USD. Wir wollen herausfinden, ob der Gesamtbetrag, der für jeden Mitarbeiter ausgegeben wurde, innerhalb des Budgets liegt oder darüber. Dazu werden wir die SUM() der Werte in vier Spalten mit dem Budget mit einer IF()-Anweisung vergleichen.

IF(SUM({Flight},{Hotel},{Insurance},{Expenses})>6500, „Über Budget“,„Gut“)  

 

Bestandsverfolgung

Du kannst dein Inventar mit monday.com ganz leicht verwalten. In diesem Beispiel wird erklärt, wie du deinen aktuell verfügbaren Bestand berechnest und wie viel Bestand verkauft wurde (als Prozentsatz).

Für die Spalte „Auf Lager“:

MINUS(MINUS({Starting Inventory},{Reserved}),{Sold})

Für die Spalte „% verkauft“:

ROUND(MULTIPLY(DIVIDE({Sold},{Starting Inventory}),100),2)

 

Formel formatieren

Durch die Verwendung der Funktion TEXT() kannst du deine Ergebnisse genau so formatieren, wie du es wünschst. Nehmen wir ein einfaches Beispiel in der ersten Zeile des folgenden Boards. Wir wollen 100 mit 25 multiplizieren, und die Ausgabe soll so aussehen: $2.500,00.

TEXT(MULTIPLY({Starting Inventory},{Cost}),"$#,##.00")

Im letzten Teil der Formel steht jedes # für eine Zahl. Wir haben .00 am Ende hinzugefügt, weil wir wollen, dass die Ausgabe mit zwei Nullen endet, aber du kannst dies durch .## ersetzen, wenn du möchtest, dass deine Ausgabe mit berechneten Zahlen endet. Das $ platziert das Symbol vor der Zahl.

Beachte, dass die Formelspalte die Zahl als Text und nicht als Zahl liest, wenn du eine Zahl mit der TEXT()-Funktion formatierst. Dies bedeutet, dass deine Spaltenzusammenfassung „N/A“ (wie oben) anstelle von Summe/Durchschnitt/etc. der in deiner Formelspalte angezeigten Zahlen anzeigt.

 

 

 

 

Wenn du Fragen hast, wende dich einfach hier an unser Team. Wir sind rund um die Uhr erreichbar und helfen gerne!